tiger-compiler/flake.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95

{
  description = "Tiger compiler flake";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-24.11";
    flake-utils = {
      url = "github:numtide/flake-utils";
      inputs.systems.follows = "systems";
    };
    systems.url = "github:nix-systems/x86_64-linux";
    buildenv = {
      url = "git+https://gitlab.lre.epita.fr/tiger/buildenv?ref=master&dir=nix";
      inputs = {
        nixpkgs.follows = "nixpkgs";
      };
    };
  };
  outputs =
    {
      self,
      nixpkgs,
      buildenv,
      flake-utils,
      ...
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs { inherit system; };
        pkgs_buildenv = buildenv.outputs.packages.${system};
      in
      {
        packages = {
          default = self.packages.${system}.tc;
          tc = pkgs.stdenv.mkDerivation {
            pname = "tc";
            version = "1.90";

            src = self;

            enableParallelBuilding = true;
            hardeningDisable = [ "all" ];

            preConfigure = ''
              patchShebangs --build ./build-aux/bin/
              patchShebangs --build ./dev/
              ./bootstrap
            '';

            nativeBuildInputs =
              with pkgs;
              [
                bison
                libxslt
                autoconf
                automake
                gnumake
                libtool
                perl
                swig4
                clang_multi
                libllvm
                multiStdenv.cc
              ]
              ++ (with pkgs_buildenv; [
                reflex
              ])
              ;

            buildInputs =
              with pkgs;
              [
                doxygen
                gdb
                graphviz
                valgrind
                libxml2
                boost
                (with pkgs.python312Packages; [
                  pyyaml
                  colorama
                  tqdm
                  lxml
                ])
              ]
              ++ (with pkgs_buildenv; [
                havm
                nolimips
              ]);
          };
        };
        formatter = pkgs.nixfmt-rfc-style;
      }
    );
}